Interfacciare SlimLine ad un termostato Shelly

PROGRAM ShellyWallDisplay

VAR CONSTANT
    BSize : UDINT := 128;    (* Buffer size definition *)
END_VAR

VAR
    CaseNr : USINT; (* Program case *)
    Errors : UDINT; (* Execution errors *)
    TimeBf : UDINT; (* Time buffer (mS) *)
    Temperature : REAL; (* Temperature °C *)
    PStart : PVOID; (* Result start position *)
    PEnd : PVOID; (* Result end position *)
    Answer : STRING[ 128 ]; (* Page string *)
    TCPClient : SysTCPClient; (* TCP client management *)
    HTTPRq : HTTPClient_v5; (* HTTP client *)
END_VAR

// *****************************************************************************
// PROGRAM "ShellyWallDisplay"
// *****************************************************************************
// The program reads the current temperature from a Shelly Wall Display.
// -----------------------------------------------------------------------------

    // -------------------------------------------------------------------------
    // INITIALIZATIONS
    // -------------------------------------------------------------------------
    // Program initializations.

    IF (SysFirstLoop) THEN

        // Set TCPClient parameters.

        TCPClient.PeerAdd:=ADR('192.168.1.109'); //Peer address
        TCPClient.PeerPort:=80; //Peer port
        TCPClient.LocalAdd:=ADR('0.0.0.0'); //Local address
        TCPClient.LocalPort:=0; //Local port
        TCPClient.FlushTm:=50; //Flush time (mS)
        TCPClient.LifeTm:=20; //Life time (S)
        TCPClient.RxSize:=512; //Rx buffer size
        TCPClient.TxSize:=512; //Tx buffer size

        // Set HTTPClient parameters.

        HTTPRq.SpyOn:=TRUE; //Activate the spy
        HTTPRq.KeepAlive:=FALSE; //HTTP keep-alive
        HTTPRq.RMethod:=HTTP_REQUEST#HTTP_POST; //HTTP request method
        HTTPRq.HostName:=TCPClient.PeerAdd; // Hostname
        HTTPRq.Page:=ADR('rpc'); //Web page
        HTTPRq.Request:=eNULL; //Request string
        HTTPRq.Header:=ADR('Content-Type: application/json$r$nAccept: application/json$r$n'); //HTTP header
        HTTPRq.DBSize:=512; //Data buffer size
        HTTPRq.Timeout:=T#10s; //Execution timeout

        // Set local variables.

        TimeBf:=SysTimeGetMs(); //Time buffer (mS)
    END_IF;

    // -------------------------------------------------------------------------
    // MANAGE CONNECTION
    // -------------------------------------------------------------------------
    // Manage the TCP/HTTP connection.

    TCPClient(Connect:=HTTPRq.Connect); //Manage TCP client
    HTTPRq(Enable:=TRUE, File:=TCPClient.File); //Enable HTTP client
    IF (HTTPRq.Fault) THEN CaseNr:=0; END_IF;

    // -------------------------------------------------------------------------
    // PROGRAM SEQUENCES
    // -------------------------------------------------------------------------
    // Program sequences.

    CASE (CaseNr) OF

        // ---------------------------------------------------------------------
        // Initialize timer for acquisition delay.

        0:
        HTTPRq.Send:=FALSE; //Do not send request yet
        TimeBf:=SysTimeGetMs(); //Time buffer (mS)
        IF (HTTPRq.Request <> eNULL) THEN eTO_JUNK(SysRMFree(ADR(HTTPRq.Request))); END_IF;
        CaseNr:=CaseNr+1; //Move to next case

        // ---------------------------------------------------------------------
        // Wait for delay, then allocate buffers and enable client.

        1:
        IF ((SysTimeGetMs()-TimeBf) < TO_UDINT(T#10s)) THEN RETURN; END_IF;
        IF NOT(SysRMAlloc(BSize, ADR(HTTPRq.Request))) THEN RETURN; END_IF;
        CaseNr:=CaseNr+1; //Program case

        // ---------------------------------------------------------------------
        // Create an RPC request to read the temperature and send it.
        // {"id":1, "method":"Temperature.GetStatus", "params":{"id":0}}

        2:
        eTO_JUNK(SysVsnprintf(HTTPRq.Request, BSize, ADR('%s'), STRING_TYPE, ADR('{"id":1, "method":"Temperature.GetStatus", "params":{"id":0}}')));
        HTTPRq.Send:=TRUE; //Send request
        CaseNr:=CaseNr+1; //Move to next case

        // ---------------------------------------------------------------------
        // Waiting for the response.
        //{"id":1,"src":"ShellyWallDisplay-0008220BB6BE","result":{"id":0,"tC":23,"tF":73.4}}

        3:
        IF ((HTTPRq.DBChars <> 0) AND HTTPRq.HPSelector) THEN
            IF ((Sysstrlen(ADR(Answer))+HTTPRq.DBChars) < SIZEOF(Answer)) THEN
                eTO_JUNK(Sysmemmove(eTO_POINTER(ADR(Answer))+Sysstrlen(ADR(Answer)), HTTPRq.DBAddress, HTTPRq.DBChars));
            END_IF;
        END_IF;

        //  On completion, read the temperature.

        IF (HTTPRq.Done) THEN
            CaseNr:=0; //Reset program case
            IF NOT(HTTPRq.PLoad) THEN Errors:=Errors+1; RETURN; END_IF;

            // Find the "result" JSON from the response.

            PStart:=SysStrFind(ADR(Answer), ADR('"result":'), FIND_GET_END); //Start position of "result"
            PEnd:=SysStrFind(PStart, ADR('}'), FIND_DEFAULT); //End position of "result"
            eTO_JUNK(Sysmemmove(ADR(Answer), PStart, TO_UDINT(PEnd-PStart)));
            IF (JSONDecoder(ADR(Answer), ADR('tC'), REAL_TYPE, ADR(Temperature), 1, 0) <> 0) THEN Errors:=Errors+1; END_IF;
        END_IF;
    END_CASE;

// [End of file]