Aggiornamento automatico FOTA dei sistemi

PROGRAM FOTAUpdate
VAR
    i : UDINT; (* Auxiliary variable *)
    FOTAStart : BOOL; (* FOTA start command *)
    Updated : BOOL; (* System has been updated *)
    CaseNr : USINT; (* Program case *)
    TimeBf : UDINT; (* Time buffer (mS) *)
    Header : STRING[ 32 ]; (* Header string *)
    FTP : FTPClient_v3; (* FTP client *)
    Logger : StringToLogFile_v3; (* Data logger *)
    LData : STRING[ 64 ]; (* Log data string *)
END_VAR

// *****************************************************************************
// PROGRAM "FOTAUpdate"
// *****************************************************************************
// By setting the FOTA command a new program file is loaded from a FTP server.
// After download system is rebooted and the new program replace the existing.
// -----------------------------------------------------------------------------

    // -------------------------------------------------------------------------
    // INITIALIZATION
    // -------------------------------------------------------------------------
    // Program initializations.

    IF (SysFirstLoop) THEN

        // FTP client definitions.

        FTP.SpyOn:=TRUE; //Spy active
        FTP.FTPServer:=ADR('server'); //Server FTP
        FTP.FTPPort:=21; //Server port
        FTP.User:=ADR('username'); //User
        FTP.Password:=ADR('password'); //Password

        FTP.LocalFile:=ADR('D:/SYSTEM.UPL'); //Local file definition
        FTP.RemoteFile:=ADR('/Firmware.upl'); //Remote file definition
        FTP.Timeout:=15.0; //Timeout (S)

        // Data logger definitions.

        Logger.Mode:=1; //AsciiHex mode
        Logger.LDLength:=0; //Log data length
        Logger.Header:=ADR(Header); //Header string
        Logger.Filename:=ADR('D:/FOTALog.txt'); //Log file

        // On startup it's controlled if the system has been updated and the
        // SYSEM.UPL file is deleted to avoid to check it at every startup.

        i:=SysOSIDValue(FALSE, OSID_UPDATE_EXECUTED, ADR(Updated));
        IF (Updated) THEN
            i:=DateTimeFormat(TO_LDATE_AND_TIME(SysDateGetNs()), ADR('^d/m/y H\:i\:s\|'), ADR(Header), SIZEOF(Header));
            i:=SysVsnprintf(ADR(LData), SIZEOF(LData), ADR('System updated, program:%s$r$n'), STRING_TYPE, ADR(SysApllName));
            Logger(LData:=ADR(LData)); //Write data to file

            IF (SysGetFileLen(ADR('D:/SYSTEM.UPL')) <> eEOF) THEN
                i:=SysFileRemove(ADR('D:/SYSTEM.UPL')); //Delete file

                // Save a log report on file.

                i:=DateTimeFormat(TO_LDATE_AND_TIME(SysDateGetNs()), ADR('^d/m/y H\:i\:s\|'), ADR(Header), SIZEOF(Header));
                Logger(LData:=ADR('System updated, update file deleted$r$n')); //Write data to file
            END_IF;
        END_IF;
    END_IF;

    // -------------------------------------------------------------------------
    // FTP CLIENT
    // -------------------------------------------------------------------------
    // Executs the FTP client and resets the commands on execution fault.

    FTP(); //FTP client
    IF (FTP.Fault) THEN CaseNr:=0; END_IF;

    // -------------------------------------------------------------------------
    // PROGRAM CASES
    // -------------------------------------------------------------------------
    // Program cases management.

    CASE (CaseNr) OF

        // ---------------------------------------------------------------------
        // EXECUTE FOTA COMMAND
        // ---------------------------------------------------------------------
        // Reset FTP commands and wait for FOTA command.

        0:
        FTP.Store:=FALSE; //Store command
        FTP.Retrieve:=FALSE; //Retrieve command
        FTP.Delete:=FALSE; //Delete command
        IF (FOTAStart) THEN CaseNr:=10; END_IF;

        // ---------------------------------------------------------------------
        // Connects to FTP server and read program file.

        10:
        FTP.Retrieve:=TRUE; //Retrieve command
        IF NOT(FTP.Done) THEN RETURN; END_IF;
        FTP.Retrieve:=FALSE; //Retrieve command
        FOTAStart:=FALSE; //FOTA start command

        // Save a log report on file.

        i:=DateTimeFormat(TO_LDATE_AND_TIME(SysDateGetNs()), ADR('^d/m/y H\:i\:s\|'), ADR(Header), SIZEOF(Header));
        Logger(LData:=ADR('Executed a FOTA update$r$n')); //Write data to file

        TimeBf:=SysTimeGetMs(); //Time buffer (mS)
        CaseNr:=CaseNr+1; //Program case

        // ---------------------------------------------------------------------
        // Waiting a while before reboot system. This is needed to allow data
        // retain.

        11:
        IF ((SysTimeGetMs()-TimeBf) < TO_UDINT(T#1m)) THEN RETURN; END_IF;
        i:=SysOSIDValue(TRUE, OSID_PLC_COMMAND, ADR('reboot'));
    END_CASE;

// [End of file]