HTTPServer, HTTP server management

• In questo topic un programma per gestire allarmi su richieste GET da telecamera.

Il programma dimostrativo Ptp194 (Download) realizza la gestione di un server HTTP con autenticazione per l’accesso. Digitando da un browser l’IP del dispositivo seguito dal numero di porta su cui il server è attivo (Esempio http://xxx.xxx.xxx.xxx:2000) verrà visualizzata la pagina di richiesta credenziali di accesso (Default Admin:Admin). Eseguito l’accesso sarà possibile navigare tra le pagine del sito.

Un pulsante di Logout dalla pagina Home.html permetterà di eseguire il logout, nel caso in cui non si eseguano accessi per un tempo superiore a 120 secondi l’utente verrà automaticamente sloggato dal sistema.

L’esempio può essere eseguito su qualunque sistema SlimLine occorre trasferire le pagine presenti nella cartella WebPages che và trasferita sul disco D: del sistema (Se non si dispone della SDCard è possibile trasferire la cartella sul disco C:, in tal caso occorre modificare la directory root nel progetto).

PROGRAM ST_HTTPServer
VAR
    CaseNr : USINT; (* Program case *)
    Error : USINT; (* Error number *)
    Counter : UDINT; (* Counter *)
    Dividend : REAL := 10.0; (* Dividend value *)
    Divisor : REAL := 1.0; (* Divisor value *)
    Result : REAL; (* Result value *)
    Ptr : @STRING; (* Auxiliary pointer *)
    RPage : STRING[ 64 ]; (* Page requested *)
    RxData : STRING[ 64 ]; (* Rx data *)
    TxData : STRING[ 128 ]; (* Tx data *)
    TxHeader : STRING[ 128 ]; (* Tx header buffer *)
    HTTPSv : HTTPServer_v2; (* HTTP server *)
END_VAR

// *****************************************************************************
// PROGRAM "ST_HTTPServer"
// *****************************************************************************
// The program instantiates a HTTP server om port 2000 that accepts up 2
// simultaneus connections.
//
// If the client (ie Web browser) connects to it and requests a page with GET
// parameters it reads the parameters and returns the page. The program can
// be tested with the example of the HTTPClient.
//
// It's possible use a browser to connect to the device IP and request:
// xxx.xxx.xxx.xxx:2000/Division.cgi?Dividend=500&Divisor=10
// it will return a message with the division result.
// -----------------------------------------------------------------------------

    // -------------------------------------------------------------------------
    // INITIALIZATIONS
    // -------------------------------------------------------------------------
    // Program initializations.

    IF (SysFirstLoop) THEN
        HTTPSv.Enable:=TRUE; //Server enable
        HTTPSv.SpyOn:=TRUE; //Spy active
        HTTPSv.Port:=2000; //TCP Port
        HTTPSv.AConnections:=2; //Accepted connections
        HTTPSv.HTTPBSize:=1024; //HTTP buffer size
        HTTPSv.HPath:=ADR('/Storage'); //Home path (ARM 7)
        HTTPSv.HPath:=ADR('/home/pi'); //Home path (Raspberry)
        HTTPSv.HPath:=ADR('C:/WPages'); //Home path (Cortex M7)
        HTTPSv.PDefault:=ADR('Home.html'); //Default page
        HTTPSv.Timeout:=2.0; //Execution timeout (S)
		HTTPSv.CORSHeader:=ADR('Access-Control-Allow-Origin: *$r$nAccess-Control-Allow-Methods: GET, POST, OPTIONS$r$nAccess-Control-Allow-Headers: Content-Type$r$n');
        HTTPSv.pTxData:=ADR(TxData); //Pointer to Tx data
    END_IF;

    // -------------------------------------------------------------------------
    // HTTP SERVER                                                           
    // -------------------------------------------------------------------------
    // Manage the server and wait until a request is received.

    HTTPSv(); //HTTP server
    HTTPSv.RAck:=FALSE; //Request acknowledge
    HTTPSv.RNAck:=FALSE; //Request not acknowledge
    IF NOT(HTTPSv.RRcvd) THEN CaseNr:=0; RETURN; END_IF;
	HTTPSv.StatusCode:=eNULL; //Status code
    HTTPSv.TxDSize:=0; //Data to send size

    // -------------------------------------------------------------------------
    // MANAGE THE REQUEST
    // -------------------------------------------------------------------------
	// The request is managed in a batch program.

    CASE (CaseNr) OF

        // ---------------------------------------------------------------------
        // WAIT FOR THE REQUEST
        // ---------------------------------------------------------------------
	    // Copy the request page with the complete path to a buffer.

		0:
		IF (Sysstrlen(HTTPSv.pPage) <= SIZEOF(RPage)) THEN
			eTO_JUNK(Sysmemmove(ADR(RPage), HTTPSv.pPage, Sysstrlen(HTTPSv.pPage)+1));
		END_IF;

		// Check if a "OPTIONS" request has been received.        

        IF (SysStrFind(HTTPSv.pRMethod, ADR('OPTIONS'), FIND_DEFAULT) <> eNULL) THEN
			HTTPSv.RAck:=TRUE; //Request acknowledge
			CaseNr:=0; //Program case
			RETURN;
		END_IF;

	    // A request has been received, is managed. Copy received data if any.

	    IF ((HTTPSv.RxDSize <> 0) AND (HTTPSv.RxDSize <= SIZEOF(RxData))) THEN
			eTO_JUNK(Sysmemmove(ADR(RxData), HTTPSv.pRxData, HTTPSv.RxDSize));
		END_IF;

	    // Check if requested a file present in the root directory,So the FB
	    // sends back the content by itself.

	    IF (HTTPSv.RFFound) THEN HTTPSv.Header:=eNULL; HTTPSv.RAck:=TRUE; RETURN; END_IF;

		// Has been request a file that is not present in the root directory.
		// Check if it's a supported script. Otherwise redirect the browser.

		IF (SysStrFind(HTTPSv.pPage, ADR('Division.cgi'), FIND_DEFAULT) <> eNULL) THEN CaseNr:=10; RETURN; END_IF;
		IF (SysStrFind(HTTPSv.pPage, ADR('AjaxPage.cgi'), FIND_DEFAULT) <> eNULL) THEN CaseNr:=20; RETURN; END_IF;
		HTTPSv.StatusCode:=ADR('HTTP/1.1 303 See Other$r$n');
		HTTPSv.Header:=ADR('Location: Redirect.html$r$n');
		HTTPSv.RNAck:=TRUE; //Request not acknowledge
		RETURN;

        // ---------------------------------------------------------------------
        // "Division.cgi" SCRIPT
        // ---------------------------------------------------------------------
		// Manage the script.

		10:
		Ptr:=SysStrFind(HTTPSv.pRxData, ADR('Dividend='), FIND_GET_END); //Auxiliary pointer
		IF (Ptr = eNULL) THEN Error:=10; CaseNr:=100; RETURN; END_IF;
		IF NOT(SysVsscanf(Ptr, ADR('%f'), REAL_TYPE, ADR(Dividend))) THEN Error:=11; CaseNr:=100; RETURN; END_IF;

		Ptr:=SysStrFind(HTTPSv.pRxData, ADR('Divisor='), FIND_GET_END); //Auxiliary pointer
		IF (Ptr = eNULL) THEN Error:=20; CaseNr:=100; RETURN; END_IF;
		IF NOT(SysVsscanf(Ptr, ADR('%f'), REAL_TYPE, ADR(Divisor))) THEN Error:=21; CaseNr:=100; RETURN; END_IF;

		Result:=Dividend/Divisor; //Result value

		HTTPSv.TxDSize:=TO_UDINT(SysVsnprintf(HTTPSv.pTxData, HTTPSv.HTTPBSize, ADR('Result=%.3f'), REAL_TYPE, ADR(Result)));
		HTTPSv.Header:=ADR('Content-Type: text/html$r$n');
	    HTTPSv.RAck:=TRUE; //Request acknowledge
		CaseNr:=0; //Program case

        // ---------------------------------------------------------------------
        // "AjaxPage.cgi" SCRIPT
        // ---------------------------------------------------------------------
		// Manage the script.

        20:
        eTO_JUNK(JSONDecoder(HTTPSv.pRxData, ADR('Dividend'), REAL_TYPE, ADR(Dividend), 1, 0));
        eTO_JUNK(JSONDecoder(HTTPSv.pRxData, ADR('Divisor'), REAL_TYPE, ADR(Divisor), 1, 0));

		// Calculate and increase counter.

		Counter:=Counter+1; //Counter
        Result:=Dividend/Divisor; //Result value

		// Return values to the browser.

	    eTO_JUNK(Sysmemset(ADR(TxData), 0, SIZEOF(TxData))); //Initialize the Tx data
	    eTO_JUNK(JSONEncoder(ADR(TxData), SIZEOF(TxData), ADR('Counter'), UDINT_TYPE, ADR(Counter), 1));
	    eTO_JUNK(JSONEncoder(ADR(TxData), SIZEOF(TxData), ADR('Dividend'), REAL_TYPE, ADR(Dividend), 1));
	    eTO_JUNK(JSONEncoder(ADR(TxData), SIZEOF(TxData), ADR('Divisor'), REAL_TYPE, ADR(Divisor), 1));
	    eTO_JUNK(JSONEncoder(ADR(TxData), SIZEOF(TxData), ADR('Result'), REAL_TYPE, ADR(Result), 1));
		HTTPSv.TxDSize:=Sysstrlen(ADR(TxData)); //Tx data size

		HTTPSv.Header:=ADR('Content-Type: application/json$r$n');
	    HTTPSv.RAck:=TRUE; //Request acknowledge
 		CaseNr:=0; //Program case

        // ---------------------------------------------------------------------
        // Arrive on request error.

        100:
        HTTPSv.TxDSize:=TO_UDINT(SysVsnprintf(HTTPSv.pTxData, HTTPSv.HTTPBSize, ADR('Error: %d, on request'), USINT_TYPE, ADR(Error)));
		HTTPSv.Header:=ADR('Content-Type: text/html$r$n');
	    HTTPSv.RAck:=TRUE; //Request acknowledge
    END_CASE;

// [End of file]