SNMPManager, sends a SNMP message

Il Simple Network Management Protocol (SNMP) è un protocollo di rete senza connessione che utilizzando connessioni UDP sulle porte 161 e 162, consente di semplificare la configurazione, gestione e supervisione (monitoring) di apparati collegati in una rete. Questo blocco funzione esegue la gestione del protocollo SNMP agendo come Manager.

In Community occorre definire l'indirizzo della stringa di definizione della comunità accettata dall'Agent. Attivando Enable viene inviato all'Agent con indirizzo Address sulla porta Port il messaggio SNMP di tipo PDUType con OID definito. Eseguito l'invio e ricevuta la risposta dall'Agent viene attivata l'uscita Done. Per inviare un nuovo pacchetto occorre disabilitare e poi riabilitare il FB.

Se il messaggio è di lettura, al termine, nella variabile indicata sarà trasferito il valore della variabile acquisita dall'Agent. Se il messaggio è di scrittura, al termine il valore della variabile definita sarà stato trasferito nell'Agent.

Function block
CODESYS: Non disponibile
LogicLab: eLLabSNMPLib

Enable (BOOL) Comando invio richiesta SNMP.

SpyOn (BOOL) Se attivo permette di spiare il funzionamento della FB.

Address (@STRING) Indirizzo IP o URL dell'Agent a cui inviare la query SNMP.

Port (UINT) Porta UDP a cui inviare la query. Solitamente si utilizza la porta 161.

Community (@STRING) Indirizzo allocazione stringa definizione Community.

PDUType (SNMP_PDU) Tipo di query SNMP da inviare.

OID (@STRING) Indirizzo stringa definizione Object Identifier.

VType (SNMP_VT) Tipo variabile ricevuta/da inviare (Vedi tabella sotto).

VAddress (@BYTE) Indirizzo allocazione variabile ricevuta/da inviare.

VLength (UDINT) Lunghezza variabile ricevuta/da inviare.

Delay (REAL) Tempo pausa di ritardo invio richiesta SNMP (S).

Timeout (REAL) Timeout esecuzione query SNMP (S).

Done (BOOL) Esecuzione comando terminata.

Ok (BOOL) Attiva per un loop di programma se comando eseguito correttamente.

Fault (BOOL) Attivo per un loop di programma se errore esecuzione.

ECode (USINT) Riporta l'eventuale codice di errore ricevuto dall'Agent.

EIndex (USINT) Riporta l'eventuale indice di errore ricevuto dall'Agent.

PDUType, definizione tipo query SNMP

PDUType	Function	Description
16#A0	GetRequest	This PDU is sent from a management station to the agent and is used to retrieve the values of object instances whose OIDs are contained in the PDU.
16#A1	GetNextRequest	This PDU is sent from a management station to the agent and is used to retrieve the values of the object instances whose OIDs are lexicographically next to that of the OID contained in the PDU.
16#A3	SetRequest	This PDU is sent from a management station to the agent and is used to set the values of object instances whose OIDs and value are contained in the PDU.

SNMP_VT, definizione tipo variabile

VType	Value	Description
INTEGER	16#02	Integer: Must refer to a signed 32bit Integer DINT variable. (Values between -2147483648 and 2147483647).
OSTRING	16#04	Octect string: Must refer to a STRING variable. Arbitrary binary or textual data, typically limited to 255 characters in length.
NULLPTR	16#05	Null: Must refer to a Null pointer.
IPADDRESS	16#40	IPAddress: Must refer to a STRING variable. An IP address in textual data, limited to 15 characters length.
COUNTER32	16#41	Counter32: Must refer to a unsigned 32bit Integer UDINT variable. Represents a non-negative integer which monotonically increases until it reaches a maximum value of 32bits-1 (4294967295 dec), when it wraps around and starts increasing again from zero.
GAUGE32	16#42	Gauge32: Must refer to a unsigned 32bit Integer UDINT variable. Represents a non-negative integer, which holds at the maximum or minimum value specified in the range when the actual value goes over or below the range, respectively.
TIMETICKS	16#43	TimeTicks: Must refer to a unsigned 32bit Integer UDINT variable. Represents an unsigned integer which represents the time, in hundredths of a second between two epochs.

ECode, definizione codice errore

ECode	Error	Descritption
0	noError	No error occurred. This code is also used in all request PDUs, since they have no error status to report.
1	tooBig	The size of the Response-PDU would be too large to transport.
2	noSuchName	The name of a requested object was not found.
3	badValue	A value in the request didn't match the structure that the recipient of the request had for the object. For example, an object in the request was specified with an incorrect length or type.
4	readOnly	An attempt was made to set a variable that has an Access value indicating that it is read-only.
5	genErr	An error occurred other than one indicated by a more specific error code in this table.
6	noAccess	Access was denied to the object for security reasons.
7	wrongType	The object type in a variable binding is incorrect for the object.
8	wrongLength	A variable binding specifies a length incorrect for the object.
9	wrongEncoding	A variable binding specifies an encoding incorrect for the object.
10	wrongValue	The value given in a variable binding is not possible for the object.
11	noCreation	A specified variable does not exist and cannot be created.
12	inconsistentValue	A variable binding specifies a value that could be held by the variable but cannot be assigned to it at this time.
13	resourceUnavailable	An attempt to set a variable required a resource that is not available.
14	commitFailed	An attempt to set a particular variable failed.
15	undoFailed	An attempt to set a particular variable as part of a group of variables failed, and the attempt to then undo the setting of other variables was not successful.
16	authorizationError	A problem occurred in authorization.
17	notWritable	The variable cannot be written or created.
18	inconsistentName	The name in a variable binding specifies a variable that does not exist.

Trigger di spy

Se SpyOn attivo è possibile utilizzare utilizzare la console di spionaggio per verificare il funzionamento della FB. Sono previsti vari livelli di triggers.

Livelli di trigger

Trigger	Descrizione
16#00000100	OID: Codifica OID in frame SNMP.
16#10000000	Lg: Log dati di esecuzione.
16#40000000	Er: Errori di esecuzione.

Errori

In caso di errore eseguendo immediatamente dopo la funzione SysGetLastError è possibile rilevare il codice di errore. Fare riferimento alla tabella seguente per la descrizione.

Codici di errore

Codice	Descrizione
10060020	FB eseguita in una task diversa dalla task di background.
10060050	Definizione Community troppo lunga
10060052	Definizione IOD troppo lunga
10060080	Timeout esecuzione.
10060090	Errore interno.
10060100~99	Errore nella codifica del comando SNMP verso Agent.
10060200~2	Errore ricezione intestazione frame risposta SNMP da Agent.
10060300~99	Errore nella decodifica della risposta SNMP ricevuta da Agent.
10060400~9	Errore dati nella risposta SNMP ricevuta da Agent.
10060410~9	Errore impostazione VType.
10060420~9	Errore impostazione VLength.

Esempi

Come utilizzare gli esempi.

ST_SNMPManager: Vengono eseguite due richieste SNMP verso un Agent su localhost (127.0.0.1), è possibile testarne il funzionamento eseguendolo su di un sistema dove è in esecuzione il programma dimostrativo del FB SNMPAgent. Viene eseguita ciclicamente una richiesta SNMP_PDU#GETRQ di un variabile SNMP_VT#INTEGER dall'agent ed il valore letto viene trasferito in Value. Value viene poi incrementato e tramite una richiesta SNMP_PDU#SETRQ inviato all'agent. In questo modo visualizzando il valore della variabile si vedrà il suo incremento nel tempo

ST_SNMPSTEDataRead: Vengono eseguite due richieste SNMP verso un dispositivo STE acquisendo il valore di temperatura e di umidità.

Per eseguire gli esempi occorre importare la libreria eLLabSNMPLib nel progetto (Articolo).

LogicLab (Ptp137) LogicLab (Ptp137)

LogicLab (Ptp137)

PROGRAM ST_SNMPManager
VAR
    IDx : USINT; (* Index *)
    Value : DINT; (* Variable value *)
    SNMPMng : SNMPManager; (* SNMP manager *)
END_VAR

// *****************************************************************************
// PROGRAM "ST_SNMPManager"
// *****************************************************************************
// A simple SNMP manager that makes SNMP queries.
// -----------------------------------------------------------------------------

    // -------------------------------------------------------------------------
    // INITIALIZATION
    // -------------------------------------------------------------------------
    // Program initialization.

    IF (SysFirstLoop) THEN
        SNMPMng.Port:=161; //Peer port
        SNMPMng.SpyOn:=TRUE; //Spy command
        SNMPMng.Community:=ADR('public'); //Community
        SNMPMng.Delay:=2.0; //Execution delay (S)
        SNMPMng.Timeout:=1.0; //Execution timeout (S)
    END_IF;

    // -------------------------------------------------------------------------
    // SNMP MANAGER
    // -------------------------------------------------------------------------
    // Check if the answer from Agent has been received and manage it.

    IF (SysFirstLoop OR SNMPMng.Done) THEN
        CASE (IDx) OF

            // -----------------------------------------------------------------
            // This query reads the variable value from the agent.

            0:
            IDx:=IDx+1; //Index
            SNMPMng.PDUType:=SNMP_PDU#GETRQ; //PDU type
             SNMPMng.VType:=SNMP_VT#INTEGER; //Variable type        
            SNMPMng.VLength:=SIZEOF(Value); //Variable length        
            SNMPMng.VAddress:=ADR(Value); //Variable address        
            SNMPMng.Address:=ADR('127.0.0.1'); //Agent address
            SNMPMng.OID:=ADR('1.3.6.1.4.1.36955.1'); //OID

            // -----------------------------------------------------------------
            // This query writes the variable value to the agent.

            1:
            IDx:=0; //Index
            Value:=Value+1; //Variable value
            SNMPMng.PDUType:=SNMP_PDU#SETRQ; //PDU type
            SNMPMng.VType:=SNMP_VT#INTEGER; //Variable type        
            SNMPMng.VLength:=SIZEOF(Value); //Variable length        
            SNMPMng.VAddress:=ADR(Value); //Variable address        
            SNMPMng.Address:=ADR('127.0.0.1'); //Agent address
            SNMPMng.OID:=ADR('1.3.6.1.4.1.36955.1'); //OID
        END_CASE;
    END_IF;

    // -------------------------------------------------------------------------
    // SNMP MANAGER
    // -------------------------------------------------------------------------
    // SNMP manager.

    SNMPMng(); //SNMP manager
    SNMPMng.Enable:=NOT(SNMPMng.Done);

// [End of file]

LogicLab (Ptp137)

PROGRAM ST_SNMPSTEDataRead
VAR
    IDx : USINT; (* Index *)
    Temperature : DINT; (* Temperature (0.1 °C) *)
    Humidity : DINT; (* Humidity (0.1 %) *)
    SNMPMng : SNMPManager; (* SNMP manager *)
END_VAR

// *****************************************************************************
// PROGRAM "ST_SNMPSTEDataRead"
// *****************************************************************************
// The program reads the temperature and humidity values from a STE device.
// -----------------------------------------------------------------------------

    // -------------------------------------------------------------------------
    // INITIALIZATION
    // -------------------------------------------------------------------------
    // Program initialization.

    IF (SysFirstLoop) THEN
        SNMPMng.Port:=161; //Peer port
        SNMPMng.SpyOn:=TRUE; //Spy command
        SNMPMng.Address:=ADR('192.168.0.223'); //Agent address
        SNMPMng.Community:=ADR('public'); //Community
        SNMPMng.Delay:=5.0; //Execution delay (S)
        SNMPMng.Timeout:=1.0; //Execution timeout (S)
    END_IF;

    // -------------------------------------------------------------------------
    // SNMP MANAGER
    // -------------------------------------------------------------------------
    // Check if the answer from Agent has been received and manage it.

    IF (SysFirstLoop OR SNMPMng.Done) THEN
        CASE (IDx) OF

            // -----------------------------------------------------------------
            // This query reads the temperature from the agent.

            0:
            IDx:=IDx+1; //Index
            SNMPMng.PDUType:=SNMP_PDU#GETRQ; //PDU type
            SNMPMng.VType:=SNMP_VT#INTEGER; //Variable type        
            SNMPMng.VLength:=SIZEOF(Temperature); //Variable length        
            SNMPMng.VAddress:=ADR(Temperature); //Variable address        
            SNMPMng.OID:=ADR('1.3.6.1.4.1.21796.4.1.3.1.5.1'); //OID

            // -----------------------------------------------------------------
            // This query reads the humidity from the agent.

            1:
            IDx:=0; //Index
            SNMPMng.PDUType:=SNMP_PDU#GETRQ; //PDU type
            SNMPMng.VType:=SNMP_VT#INTEGER; //Variable type        
            SNMPMng.VLength:=SIZEOF(Humidity); //Variable length        
            SNMPMng.VAddress:=ADR(Humidity); //Variable address        
            SNMPMng.OID:=ADR('1.3.6.1.4.1.21796.4.1.3.1.5.2'); //OID
        END_CASE;
    END_IF;

    // -------------------------------------------------------------------------
    // SNMP MANAGER
    // -------------------------------------------------------------------------
    // SNMP manager.

    SNMPMng(); //SNMP manager
    SNMPMng.Enable:=NOT(SNMPMng.Done);

// [End of file]

Trigger di spy

Errori

Esempi

Ti è stato utile questo articolo ?

Footer