HTTPClient, HTTP client

HTTPClient_v4

Viene gestita la connessione HTTP Keep Alive nativa dell’HTTP 1.1, per gestirla si è aggiunto il comando Send. Attivando Enable viene comandata la sola connessione al server HTTP, per inviare la richiesta occorre attivare Send. Ricevuta la risposta la connessione rimane attiva per la prossima richiesta, per chiudere la connessione disabilitare Enable.

HTTPClient_v5

Modificata gestione connessione HTTP Keep Alive, aggiunto parametri KeepAlive e KAAccepted, attivando permanentemente Enable, il comando Send, gestisce la connessione automaticamente. Modificato parametro RMethod ora è di tipo HTTP_REQUEST. Modificato tipo parametri Timeout e PLTime ora sono di tipo TIME.

Molti servizi REST API richiedono l’autenticazione, esistono diversi tipi di autenticazione i più utilizzati sono il Basic e Digest utilizzati per le autenticazioni basate su credenziali di accesso (Nome utete e password) ed il Bearer utilizzato per autenticazione con token. L’autenticazione deve essere passata nell’header di accesso all’API, i valori di autenticazione sono passati codificati in Base64, esistono molti codificatori on-line che provvedono alla codifica/decodifica.

Particolare attenzione và posta nella codifica delle credenziali definendo username e password separate da “:”. Quindi ad esempio per l’utente Root con password MyPassword codificando la stringa Root:MyPassword, avremo: HTTPRq.Header:=ADR(‘Authorization: Basic Um9vdDpNeVBhc3N3b3Jk$r$n’);

Da notare che dopo la definizione della stringa Base64 ho inserito il <CR><LF> ($r$n) di terminazione campo.

PROGRAM ST_HTTPClient
VAR
    CaseNr : USINT; (* Program case *)
    Errors : UDINT; (* Execution errors *)
    TimeBf : UDINT; (* Time buffer (mS) *)
    Page : STRING[ 64 ]; (* Page string *)
    Header : STRING[ 256 ]; (* Header string *)
    TCPClient : SysTCPClient; (* TCP client management *)
    HTTPRq : HTTPClient_v5; (* HTTP client *)
END_VAR

// *****************************************************************************
// PROGRAM "ST_HTTPClient"
// *****************************************************************************
// The program connects to a server om which is running a PHP script like:
//
// 
//
// The program sends the "Dividend" and "Divisor" values and receives back from
// the server the result. If the server answers correctly the following result
// is expected.
//
// Header: 'HTTP/1.1 200 OK...
// Page: 'The result is: 50'
// -----------------------------------------------------------------------------

    // -------------------------------------------------------------------------
    // INITIALIZATIONS
    // -------------------------------------------------------------------------
    // Program initializations.

    IF (SysFirstLoop) THEN

        // Set TCPClient parameters.

        TCPClient.PeerAdd:=ADR('demos.elsist.biz'); //Peer address
        TCPClient.PeerPort:=80; //Peer port
        TCPClient.LocalAdd:=ADR('0.0.0.0'); //Local address
        TCPClient.LocalPort:=0; //Local port
        TCPClient.FlushTm:=50; //Flush time (mS)
        TCPClient.LifeTm:=20; //Life time (S)
        TCPClient.RxSize:=512; //Rx buffer size
        TCPClient.TxSize:=512; //Tx buffer size

        // Set HTTPClient parameters.

        HTTPRq.SpyOn:=TRUE; //Activate the spy
        HTTPRq.KeepAlive:=FALSE; //HTTP keep-alive
        HTTPRq.RMethod:=HTTP_REQUEST#HTTP_GET; //HTTP request method
        HTTPRq.HostName:=TCPClient.PeerAdd; // Hostname
        HTTPRq.Page:=ADR('eLLabHTTPLib/HTTPClient/ST_HTTPClient.php'); //Web page
        HTTPRq.Request:=ADR('Dividend=500$26Divisor=10'); //Request string
        HTTPRq.Header:=ADR('Accept: application/json$r$n'); //HTTP header
        HTTPRq.DBSize:=512; //Data buffer size
        HTTPRq.Timeout:=T#10s; //Execution timeout

        // Set local variables.

        TimeBf:=SysTimeGetMs(); //Time buffer (mS)
    END_IF;

    // -------------------------------------------------------------------------
    // MANAGE CONNECTION
    // -------------------------------------------------------------------------
    // Manage the connection.

    TCPClient(Connect:=HTTPRq.Connect); //TCPClient management
    HTTPRq(Enable:=TRUE, File:=TCPClient.File); //HTTP client
    IF (HTTPRq.Fault) THEN CaseNr:=0; END_IF;

    // -------------------------------------------------------------------------
    // PROGRAM SEQUENCIES
    // -------------------------------------------------------------------------
    // Program sequencies.

    CASE (CaseNr) OF

        // ---------------------------------------------------------------------
        // Initialize the time to manage acquisition delay.

        0:
        HTTPRq.Send:=FALSE; //Send request
        TimeBf:=SysTimeGetMs(); //Time buffer (mS)
        CaseNr:=CaseNr+1; //Program case

        // ---------------------------------------------------------------------
        // Wait delay time then initialize buffers and enable client.

        1:
        IF ((SysTimeGetMs()-TimeBf) < TO_UDINT(T#5s)) THEN RETURN; END_IF;
        eTO_JUNK(Sysmemset(ADR(Header), 0, SIZEOF(Header))); //Empty header string
        eTO_JUNK(Sysmemset(ADR(Page), 0, SIZEOF(Page))); //Empty page string
        HTTPRq.Send:=TRUE; //Send request
        CaseNr:=CaseNr+1; //Program case

        // ---------------------------------------------------------------------
        // Header/Page data are received from server by chunked. When a chunk
        // has been received DBChars returns its length.

        2:
        IF (HTTPRq.DBChars <> 0) THEN

            // Transfer the received chunk on the proper buffer.

            IF NOT(HTTPRq.HPSelector) THEN
                IF ((Sysstrlen(ADR(Header))+HTTPRq.DBChars) < SIZEOF(Header)) THEN
                    eTO_JUNK(Sysmemmove(TO_DWORD(ADR(Header))+Sysstrlen(ADR(Header)), HTTPRq.DBAddress, HTTPRq.DBChars));
                END_IF;
            ELSE
                IF ((Sysstrlen(ADR(Page))+HTTPRq.DBChars) < SIZEOF(Page)) THEN
                    eTO_JUNK(Sysmemmove(TO_DWORD(ADR(Page))+Sysstrlen(ADR(Page)), HTTPRq.DBAddress, HTTPRq.DBChars));
                END_IF;
            END_IF;
        END_IF;

        // On Done it's possible to test if page has been loaded.

        IF (HTTPRq.Done) THEN
            IF NOT(HTTPRq.PLoad) THEN Errors:=Errors+1; END_IF;
            CaseNr:=0; //Program case
        END_IF;
    END_CASE;

// [End of file]

PROGRAM ST_HTTPClient_ToFile
VAR
    Execute : BOOL; (* Execute command *)
    CaseNr : USINT; (* Program case *)
    Fp : eFILEP; (* File pointer *)
    Error : USINT; (* Execution error *)
    HFile : STRING[ 32 ]; (* Header storage file definition *)
    PFile : STRING[ 32 ]; (* Page storage file definition *)
    TCPClient : SysTCPClient; (* TCP client management *)
    HTTPRq : HTTPClient_v5; (* HTTP client *)
END_VAR

// *****************************************************************************
// PROGRAM "ST_HTTPClient_ToFile"
// *****************************************************************************
// The program connects to a server om which is running a PHP script that
// returns 4Kb of text.
// THe header and the page returned are stored into a files.
// -----------------------------------------------------------------------------

    // -------------------------------------------------------------------------
    // INITIALIZATIONS
    // -------------------------------------------------------------------------
    // Program initializations.

    IF (SysFirstLoop) THEN

        // Set TCPClient parameters.

        TCPClient.PeerAdd:=ADR('demos.elsist.biz'); //Peer address
        TCPClient.PeerPort:=80; //Peer port
        TCPClient.LocalAdd:=ADR('0.0.0.0'); //Local address
        TCPClient.LocalPort:=0; //Local port
        TCPClient.FlushTm:=50; //Flush time (mS)
        TCPClient.LifeTm:=20; //Life time (S)
        TCPClient.RxSize:=512; //Rx buffer size
        TCPClient.TxSize:=512; //Tx buffer size

        // Set HTTPClient parameters.

        HTTPRq.SpyOn:=TRUE; //Activate the spy
        HTTPRq.KeepAlive:=FALSE; //HTTP keep-alive
        HTTPRq.RMethod:=HTTP_REQUEST#HTTP_GET; //HTTP request method
        HTTPRq.HostName:=TCPClient.PeerAdd; // Hostname
        HTTPRq.Page:=ADR('eLLabHTTPLib/HTTPClient/ST_HTTPClient_ToFile.php'); //Web page
        HTTPRq.Request:=eNULL; //Request string
        HTTPRq.Header:=eNULL; //HTTP header
        HTTPRq.DBSize:=512; //Data buffer size
        HTTPRq.Timeout:=T#10s; //Execution timeout

        // Set local variables.
        // Store data file definition, change according your requirements.

        HFile:='D:/Header.txt'; //Header file definition    
        PFile:='D:/Page.txt'; //Page file definition    
    END_IF;

    // -------------------------------------------------------------------------
    // MANAGE CONNECTION
    // -------------------------------------------------------------------------
    // Manage the connection.

    TCPClient(Connect:=HTTPRq.Connect); //TCPClient management
    HTTPRq(Enable:=TRUE, File:=TCPClient.File); //HTTP client

    // -------------------------------------------------------------------------
    // PROGRAM SEQUENCIES
    // -------------------------------------------------------------------------
    // Program sequencies.

    CASE (CaseNr) OF

        // ---------------------------------------------------------------------
        // Wait for the command.

        0:
        HTTPRq.Send:=FALSE; //Send request
        IF NOT(Execute) THEN RETURN; END_IF;
        Execute:=FALSE; //Execute command
        Error:=0; //Execution error

        // Initialize buffers and enable client.

        eTO_JUNK(SysFileRemove(ADR(HFile))); //Delete the header storage file
        eTO_JUNK(SysFileRemove(ADR(PFile))); //Delete the pge storage file
        HTTPRq.Enable:=TRUE; //HTTP enable
        HTTPRq.Send:=TRUE; //Send request
        CaseNr:=CaseNr+1; //Program case

        // ---------------------------------------------------------------------
        // Header/Page data are received from server by chunked. When a chunk
        // has been received DBChars returns its length.

        1:
        IF (HTTPRq.DBChars <> 0) THEN

            // Transfer the received chunk on the proper file.

            IF NOT(HTTPRq.HPSelector) THEN
                Fp:=SysFfopen(ADR(HFile), ADR('a')); //File pointer
            ELSE
                Fp:=SysFfopen(ADR(PFile), ADR('a')); //File pointer
            END_IF;

            // Open the file in append mode, if it doesn't exist i'll be created.

            IF (Fp = eNULL) THEN Error:=10; CaseNr:=0; RETURN; END_IF;

            // Transfer received data to file.

            IF (Sysfwrite(HTTPRq.DBAddress, TO_INT(HTTPRq.DBChars), 1, Fp) <> TO_INT(HTTPRq.DBChars)) THEN
                Fp:=FClose(Fp); //Close the file
                Error:=20; //Execution error
                CaseNr:=0; //Program case
                RETURN;
            END_IF;

            Fp:=FClose(Fp); //Close the file
        END_IF;

        // Check if request done.
        // On Done it's possible to test if page has been loaded.

        IF (HTTPRq.Done) THEN
            IF NOT(HTTPRq.PLoad) THEN Error:=30; END_IF;
            CaseNr:=0; //Program case
        END_IF;
    END_CASE;

// [End of file]