FIFOFile, gestisce registro FIFO su file

Se i dati del registro sono memorizzati su di un file di appoggio è possibile scaricare dal sistema il file, aprirlo con l’utility FIFOViewer (https://utilities.elsist.biz/FIFOViewer.html) che lo decodifica e ne visualizza il contenuto ordinato per Data/Ora. L’indicazione di Data/Ora è stata automaticamente abbinata dal FB nel momento in cui il record è stato inserito nel registro.

Utilizzando il tasto di download è possibile salvare il contenuto del file decodificato così come visualizzato.

PROGRAM ST_FIFOFile
VAR
    Out : BOOL; (* Extract record from FIFO *)
    In : BOOL; (* Insert record on FIFO *)
    i : UDINT; (* Auxiliary variable *)
    FIFOIn : STRING[ 32 ]; (* FIFO data Input *)
    Counter : UDINT; (* Counter *)
    FIFOIDx : ARRAY[0..1] OF UDINT; (* FIFO indexes *)
    FIFOOut : STRING[ 32 ]; (* FIFO data Output *)
    FIFO : FIFOFile_v1; (* FIFO file FB instance *)
END_VAR

// *****************************************************************************
// PROGRAM "ST_FIFOFile"
// *****************************************************************************
// By setting In command a record is inserted on the FIFO register. By setting
// Out command if present a record is extracted from the FIFO register.
// -----------------------------------------------------------------------------

    // -------------------------------------------------------------------------
    // INITIALIZATION
    // -------------------------------------------------------------------------
    // Execute program initialization.

    IF (SysFirstLoop) THEN
         FIFO.FIFOFilename:=ADR('C:/FIFO.bin'); //Filename
    //    FIFO.FIFOFilename:=ADR('D:/FIFO.bin'); //Filename
   //     FIFO.FIFOFilename:=eNULL; //Filename
        FIFO.FIFOIDx:=ADR(FIFOIDx); //FIFO indexes
        FIFO.FIFOSize:=10000; //FIFO register size

        // Wear leveling, if the two indexes have the same value delete
        // the FIFO file. I'll be created in a new disk position.

        IF (SysGetFileLen(FIFO.FIFOFilename) <> -1) THEN
            IF (FIFOIDx[0] = FIFOIDx[1]) THEN i:=SysFileRemove(FIFO.FIFOFilename); FIFOIDx[0]:=0; FIFOIDx[1]:=0; END_IF;
        END_IF;
    END_IF;

    // Execute FIFO register, to manage the output variables.

    FIFO(); //FIFO file FB instance

    // -------------------------------------------------------------------------
    // INSERT DATA ON FIFO REGISTER
    // -------------------------------------------------------------------------
    // If In command is set counter is increased and its value stored on FIFO.

    IF (In) THEN
        In:=FALSE; //Insert record on FIFO

        // Increase the counter and add value to FIFO.

        Counter:=Counter+1; //Counter
        i:=SysVsnprintf(ADR(FIFOIn), SIZEOF(FIFOIn), ADR('Counter=%d'), UDINT_TYPE, ADR(Counter));
        FIFO(In:=TRUE, Dp:=ADR(FIFOIn), Dls:=LEN(FIFOIn)); //Write record on FIFO
    END_IF;

    // -------------------------------------------------------------------------
    // EXTRACT DATA FROM FIFO REGISTER
    // -------------------------------------------------------------------------
    // If Out command is set a record is extracted from FIFO register.

    IF (Out AND FIFO.DataOn) THEN
        Out:=FALSE; //Extract record from FIFO

        FIFO(Out:=TRUE, Dp:=ADR(FIFOOut), Dls:=SIZEOF(FIFOOut)); //Read record from FIFO
        FIFO(Delete:=TRUE); //Delete record from FIFO
    END_IF;

// [End of file]

PROGRAM ST_FIFO_DataLog
VAR
    Store : BOOL; (* Store command *)
    i : UDINT; (* Auxiliary variable *)
    Fp : eFILEP; (* File pointer *)
    TimeBf : UDINT; (* Time buffer (uS) *)
    AStr : STRING[ 64 ]; (* Auxiliary string *)
    FIFO : FIFOFile_v1; (* FIFO file FB instance *)
END_VAR

// *****************************************************************************
// PROGRAM "ST_FIFO_DataLog"
// *****************************************************************************
// By setting In command a record is inserted on the FIFO register. By setting
// Out command if present a record is extracted from the FIFO register.
// -----------------------------------------------------------------------------

    // -------------------------------------------------------------------------
    // INITIALIZATION
    // -------------------------------------------------------------------------
    // Execute program initialization.

    IF (SysFirstLoop) THEN
        FIFO.FIFOFilename:=NULL; //Filename
        FIFO.FIFOIDx:=NULL; //FIFO indexes
        FIFO.FIFOSize:=4096; //FIFO register size
    END_IF;

    // Execute FIFO register, to manage the output variables.

    FIFO(); //FIFO file FB instance

    // -------------------------------------------------------------------------
    // STORE LOG RECORD ON FIFO
    // -------------------------------------------------------------------------
    // On Store command, prepares the log record and store it on FIFO. The 
    // record is: "14/02/2020 10:30:02 Back execution time:138 (uS)". 

    IF (Store) THEN
        Store:=FALSE; //Store command
        i:=DateTimeFormat(TO_LDATE_AND_TIME(SysDateGetNs()), ADR('^d/m/Y H\:i\:s'), ADR(AStr), SIZEOF(AStr));
        i:=SysCVsnprintf(ADR(AStr), SIZEOF(AStr), ADR('Back execution time:%d (uS)'), UDINT_TYPE, ADR(SysTBackExTm));
        FIFO(In:=TRUE, Dp:=ADR(AStr), Dls:=Sysstrlen(FIFO.Dp)); //Write record on FIFO
    END_IF;

    // -------------------------------------------------------------------------
    // WRITE LOG RECORD ON FILE
    // -------------------------------------------------------------------------
    // When FIFO as an considerable amount of data on it, the data are written
    // on disk. So the disk access is optimized. If the data stored on FIFO
    // don't reach the write threshold, they are written after a time.

    IF NOT(FIFO.DataOn) THEN TimeBf:=SysTimeGetMs(); RETURN; END_IF;
    IF ((SysTimeGetMs()-TimeBf) < TO_UDINT(T#2s)) AND (FIFO.FIFOSpace > (FIFO.FIFOSize/2)) THEN RETURN; END_IF;

    // Open the file on append, if not present it will be created.

    Fp:=SysFfopen(ADR('D:/Log.txt'), ADR('a')); //File pointer
    IF (Fp = NULL) THEN RETURN; END_IF;

    // Extract data from FIFO.

    WHILE (FIFO.DataOn) DO
        FIFO(Out:=TRUE, Dp:=ADR(AStr), Dls:=SIZEOF(AStr));

        // Write data on file.

        i:=Sysfwrite(ADR(AStr), TO_INT(Sysstrlen(ADR(AStr))), 1, Fp);
        i:=Sysfwrite(ADR('$r$n'), 2, 1, Fp);
        FIFO(Delete:=TRUE); //Delete record from FIFO
    END_WHILE;

    // Close the file.

    i:=Sysfclose(Fp); //Eseguo chiusura file

// [End of file]