HMIAInOnePicoface, Manages the Picoface HMI

  1. Home
  2. Knowledge Base
  3. Manualistica
  4. Programmazione IEC 61131-3
  5. Libreria utilità generale
  6. HMIAInOnePicoface, Manages the Picoface HMI

Questo blocco funzione esegue la gestione del terminale Picoface, il terminale può essere connesso al sistema su bus di estensione I2C oppure in seriale sia in configurazione FullDuplexRS232 che in configurazione HalfDuplex RS485. Il parametro CType definisce il tipo di comunicazione utilizzata. Il FB deve essere eseguito in task Back.

Attivando l'ingresso Enable si attiva l'uscita Enabled e viene gestito il terminale acquisendo i tasti e gestendo i LEDs, sul display viene visualizzato il messaggio (32 caratteri) il cui indirizzo è indicato in DData. In DvCmd può essere passata una stringa di definizione del comportamento di ogni digit del display, permettendo di eseguirne il lampeggio alternato con uno space, con il simbolo - o il simbolo +.

Attivando i bits in ingresso è possibile comandare i LEDs e le uscite logiche poste sul terminale, in uscita è ritornato lo stato dei tasti e degli ingressi logici posti sul terminale. Questo permette di utilizzarli nel proprio programma come comandi.

Function block
CODESYS: Non disponibile
LogicLab: eLLabUtyLib

Enable (BOOL) Comando di abilitazione blocco funzione.

SpyOn (BOOL) Se attivo permette di spiare il funzionamento della FB (Vedi articolo).

CType (BOOL) Tipo comunicazione. FALSE: Full duplex (Default), TRUE: Half duplex.

File (FILEP) Flusso dati stream di gestione HMI, per il terminale connesso in I2C definire PCOM15.1.

FLed0~6 (BOOL) Comando LED tasti funzione da [0] a [6].

Backlight (BOOL) Comando accensione backlight display.

Out0~1 (BOOL) Comando uscite logiche del terminale.

DVCmd (@STRING) Stringa definizione modo visualizzazione digit sul display.

DData (@STRING) Stringa da visualizzare sul display.

DEStart (BOOL) Comando start inputazione variabile.

DEType (VR_TYPE) Tipo variabile in inputazione (Vedi definizione).

DEPosition (USINT) Posizione sul display di inputazione variabile.

DELength (USINT) Numero di digit variabile in inputazione.

DEValue (UDINT) Indirizzo buffer memorizzazione valore inputato.

Enabled (BOOL) Attivo su abilitazione blocco funzione.

Ready (BOOL) Attivo se il terminale è pronto.

Fault (BOOL) Attivo per un loop su errore esecuzione.

FKey0~9 (BOOL) Stato tasti funzione da [0] a [9] del terminale.

KeyFUN (BOOL) Stato tasto [FUN] del terminale.

KeyESC (BOOL) Stato tasto [ESC] del terminale.

KeyENT (BOOL) Stato tasto [ENT] del terminale.

KeyUP (BOOL) Stato tasto [UP] del terminale.

KeyDW (BOOL) Stato tasto [DW] del terminale.

Inp0~1 (BOOL) Stato ingressi digitali del terminale.

DEAbort (BOOL) Attivo per un loop su abort sequenza inputazione.

DEEnd (BOOL) Attivo per un loop al termine della sequenza di inputazione, il dato inputato è trasferito nel buffer puntato da DEValue.

PCode (STRING[10]) Codice terminale Picoface, viene acquisito dal terminale.

SCode (STRING[10]) Versione software terminale Picoface, viene acquisito dal terminale.

OneWireOk (BOOL) Attivo se almeno un dispositivo One-Wire è connesso al connettore del terminale.

OneWireTrig (BOOL) Attivo per un loop di programma, da usare come trigger sull'array OneWireData.

OneWireData (BYTE[16]) Ritorna i dati letti dal dispositivo One Wire connesso al connettore del terminale.

Errori

In caso di errore eseguendo immediatamente dopo la funzione SysGetLastError è possibile rilevare il codice di errore. Fare riferimento alla tabella seguente per la descrizione.

Esempi

Come utilizzare gli esempi.

ST_HMIAInOnePicoface: Viene gestita una visualizzazione a menù, alla attivazione viene visualizzato un messaggio di benvenuto e dopo pochi secondi si visualizza il menù. Dal quado di menù premendo il tasto [0] si passa alla visualizzazione di un messaggio con la data e ora, col tasto [CLR] si ritorna al menù.

ST_DataEntryOnPicoface: Struttura a menù come nel precedente esempio ma oltre al quadro Data/Ora vi è un quadro che visualizza due variabili. Agendo sul tasto [FUN] è possibile scegliere la variabile di cui eseguire l'inputazione del valore (Diventa lampeggiante). Il tasto [CLR] abilita l'inputazione, accettando il valore con [ENT] il valore inputato verrà memorizzato nella relativa variabile.

LogicLab (Ptp114)
PROGRAM ST_HMIAInOnePicoface
VAR
    i : UDINT; (* Auxiliary counter *)
    ScreenIDx : USINT; (* Screen index *)
    TimeBf : UDINT; (* Time buffer (uS) *)
    Sp : SysSerialPort; (* Serial port management *)
    HMI : HMIAInOnePicoface; (* Picoface terminal *)
    DData : STRING[ 32 ]; (* Display data *)
    DTime : SysETimeToDate; (* Conversione in Data/Ora *)
END_VAR

// *****************************************************************************
// PROGRAM "ST_HMIAInOnePicoface"
// *****************************************************************************
// An example how to use the Picoface HMI.
// -----------------------------------------------------------------------------

    // -------------------------------------------------------------------------
    // INITIALIZATION
    // -------------------------------------------------------------------------

    IF (SysFirstLoop) THEN

        // Initialize the pheripheral COM port used to manage the HMI.

        Sp.COM:=ADR('PCOM15.1'); //COM port definition
        Sp.Baudrate:=115200; //Baudrate
        Sp.Parity:='E'; //Parity
        Sp.DataBits:=8; //Data bits
        Sp.StopBits:=1; //Stop bits
        Sp.DTRManagement:=DTR_AUTO_WO_TIMES; //DTR management
        Sp.DTRComplement:=FALSE; //DTR complement
        Sp.EchoFlush:=FALSE; //Received echo flush
        Sp.DTROnTime:=0; //DTR On time delay (mS)
        Sp.DTROffTime:=0; //DTR Off time delay (mS)
        Sp.FlushTm:=0; //Flush time (mS)
        Sp.RxSize:=0; //Rx buffer size
        Sp.TxSize:=0; //Tx buffer size

        // Initialize HMI FB.

        HMI.SpyOn:=TRUE; //Spy On
        HMI.CType:=FALSE; //Communication type
        HMI.DData:=ADR(DData); //Display data
    END_IF;

    // -------------------------------------------------------------------------
    // PICOFACE MANAGEMENT
    // -------------------------------------------------------------------------
    // Here manages the HMI.
    
    Sp(Open:=TRUE); //Serial port management
    HMI.File:=Sp.File; //File pointer
    HMI(Enable:=Sp.Opened); //Picoface terminal

    // Display data and view command are set as default, this is made after FB
    // execution to allow the following program instructions to overwrite them.

    HMI.DData:=ADR(DData); //Display data
    HMI.DVCmd:=ADR('                                '); //Display view command

    // Function key LEDs are switched off, this is made after FB execution to
    // allow the following program instructions to switch on them.

    HMI.FLed0:=FALSE; //LED command [0]
    HMI.FLed1:=FALSE; //LED command [1]
    IF NOT(HMI.Ready) THEN ScreenIDx:=0; RETURN; END_IF;   

    // -------------------------------------------------------------------------
    // MESSAGE DISPLAY
    // -------------------------------------------------------------------------
    // By using the ScreenIDx variable some messages are displayed.

    CASE (ScreenIDx) OF

        // ---------------------------------------------------------------------
        // SELECTION SCREENS
        // ---------------------------------------------------------------------
        // At system power up a welcome screen is displayed.
        // +----------------+
        // |Hello!          |
        // |I am Picoface   |
        // +----------------+

        0:
        TimeBf:=SysGetSysTime(TRUE); //Time buffer (uS)
        ScreenIDx:=ScreenIDx+1; //Screen index

        // ---------------------------------------------------------------------
        // The welcome message is displayed for a while.

        1:      
        HMI.DData:=ADR('Hello!          I am Picoface   '); //Display data
        IF ((SysGetSysTime(TRUE)-TimeBf) > 2000000) THEN ScreenIDx:=10; END_IF;

        // ---------------------------------------------------------------------
        // The menu message is displayed, the "keyboard" string is blinking.
        // +----------------+
        // |Use keyboard to |
        // |make your choice|
        // +----------------+

        10:
        HMI.DData:=ADR('Use keyboard to make your choice'); //Display data
        HMI.DVCmd:=ADR('    ********                    '); //Display view command
        
        // Blink the function key LEDs.

        HMI.FLed0:=SysClock1000; //LED command [0]

        // By pressing the function key [0] the Data/Time message is displayed.
        
        IF (HMI.FKey0) THEN ScreenIDx:=50; END_IF; //Date and time display

        // ---------------------------------------------------------------------
        // DATE/TIME MESSAGE
        // ---------------------------------------------------------------------
        // The date and time is displayed, exit by pressing the [ESC] key.
        // +----------------+
        // |Date:xx/xx/xxxx |
        // |Time:xx:xx:xx   |
        // +----------------+

        50:
        HMI.FLed0:=TRUE; //LED command [0]
        DTime(EpochTime:=SysDateTime); //Convert Epoch time

        i:=SysVsnprintf(ADR(DData), SIZEOF(DData), ADR('Date:%02d/'), USINT_TYPE, ADR(DTime.Day));
        i:=SysCVsnprintf(ADR(DData), SIZEOF(DData), ADR('%02d/'), USINT_TYPE, ADR(DTime.Month));
        i:=SysCVsnprintf(ADR(DData), SIZEOF(DData), ADR('%04d '), UINT_TYPE, ADR(DTime.Year));

        i:=SysCVsnprintf(ADR(DData), SIZEOF(DData), ADR('Time:%02d:'), USINT_TYPE, ADR(DTime.Hour));
        i:=SysCVsnprintf(ADR(DData), SIZEOF(DData), ADR('%02d:'), USINT_TYPE, ADR(DTime.Minute));
        i:=SysCVsnprintf(ADR(DData), SIZEOF(DData), ADR('%02d   '), UINT_TYPE, ADR(DTime.Second));
        IF (HMI.KeyESC) THEN ScreenIDx:=10; END_IF;
    END_CASE;

// [End of file]
LogicLab (Ptp114)

Ti è stato utile questo articolo ?

Ultimo aggiornamento: 17 Agosto 2020