SNMPAgent, manages the SNMP Agent

PROGRAM ST_SNMPAgent
VAR
    Value : DINT := [-1350]; (* Integer variable *)
    SIDx : USINT; (* Socket index *)
    Fp : ARRAY[0..1] OF eFILEP; (* File pointer *)
    VDefs : ARRAY[0..2] OF SNMPVARIABLEDEFS; (* Variable definitions *)
    UDPServer : SysUDPServer; (* UDP server *)
    SNMPAgt : SNMPAgent; (* SNMP agent *)
END_VAR

// *****************************************************************************
// PROGRAM "ST_SNMPAgent"
// *****************************************************************************
// A simple SNMP agent that responding to manager inquiries. It publish 3 OIDs.
// -----------------------------------------------------------------------------

    // -------------------------------------------------------------------------
    // INITIALIZATION
    // -------------------------------------------------------------------------
    // Program initialization

    IF (SysFirstLoop) THEN

        // Set UDP server parameters.

        UDPServer.FilesArr:=ADR(Fp); //Files array
        UDPServer.LocalAdd:=ADR('0.0.0.0'); //Local address
        UDPServer.LocalPort:=161; //Local port
        UDPServer.MaxConn:=TO_USINT(SIZEOF(Fp)/SIZEOF(Fp[0])); //Accepted connections
        UDPServer.FlushTm:=50; //Flush time (mS)
        UDPServer.LifeTm:=5; //Life time (S)
        UDPServer.RxSize:=512; //Rx buffer size
        UDPServer.TxSize:=512; //Tx buffer size

        // Parametrize the SNMP Agent FB.

        SNMPAgt.SpyOn:=TRUE; //Spy command
        SNMPAgt.Community:=ADR('public'); //Community
        SNMPAgt.VDefs:=ADR(VDefs); //Variable definitions
        SNMPAgt.VNr:=SIZEOF(VDefs)/SIZEOF(VDefs[0]); //Variable number
        SNMPAgt.Timeout:=T#5s; //Timeout

        // Definition of the variables on which the Agent can operate.

        VDefs[0].VType:=SNMP_VT#INTEGER; //Variable type
        VDefs[0].Writable:=TRUE; //Variable can be written
        VDefs[0].OID:=ADR('1.3.6.1.4.1.36955.1'); //OID definition
        VDefs[0].Address:=ADR(Value); //Variable address
        VDefs[0].Length:=SIZEOF(Value); //Variable length

        VDefs[1].VType:=SNMP_VT#OSTRING; //Variable type
        VDefs[1].Writable:=FALSE; //Variable cannot be written
        VDefs[1].OID:=ADR('1.3.6.1.4.1.36955.2'); //OID definition
        VDefs[1].Address:=ADR('Hello!'); //Variable address
        VDefs[1].Length:=Sysstrlen(VDefs[1].Address); //Variable length

        VDefs[2].VType:=SNMP_VT#IPADDRESS; //Variable type
        VDefs[2].Writable:=FALSE; //Variable cannot be written
        VDefs[2].OID:=ADR('1.3.6.1.4.1.36955.3'); //OID definition
        VDefs[2].Address:=ADR('192.168.0.12'); //Variable address
        VDefs[2].Length:=Sysstrlen(VDefs[2].Address); //Variable length
    END_IF;

    // -------------------------------------------------------------------------
    // SNMP AGENT MANAGEMENT
    // -------------------------------------------------------------------------
    // Manage the SNMP Agent.

    UDPServer(Enable:=TRUE); //UDP server
    SNMPAgt(File:=Fp[SIDx], Enable:=TRUE); //SNMP Agent
    IF NOT(SNMPAgt.Busy) THEN SIDx:=SIDx+1; IF (SIDx >= UDPServer.MaxConn) THEN SIDx:=0; END_IF; END_IF;

// [End of file]