Telegram, manages Telegram messenger through web APIs

• Se l’oggetto aggiornato non è nell’ultima versione del package, vedi capitolo “Aggiornamento librerie” in questo articolo.
• Gli oggetti obsoleti sono inseriti nella libreria eLLabObsoleteLib fare riferimento al relativo manuale ed al manuale programmazione in formato pdf.

Telegram_v1

Utilizza la nuova versione FB HTTPClient_v5.

Naturalmente i bot non hanno un numero di telefono abbinato, per inviare un messaggio ad un bot o ad un utente di cui non conosci il numero ti basta conoscere il loro username, in modo da cercarlo nel motore di ricerca dell’app.

Avvia l’app di Telegram e premi sul campo di testo Cerca situato in corrispondenza dell’icona della lente di ingrandimento, poi digita il nome utente della persona od il nome del bot a cui vuoi inviare il messaggio e selezionalo nei risultati della ricerca. Ora puoi digitare il testo del messaggio nel campo di testo ed inviarlo, premendo sull’icona della freccia situata in basso.

Per inviare un messaggio ad un utente Telegram occorre conoscere il chat id. Per conoscere il proprio chat id avvia l’app di Telegram e premi sul campo di testo Cerca situato in corrispondenza dell’icona della lente di ingrandimento, poi digita userinfobot, e selezionalo nei risultati della ricerca. Ora basta inviare un qualsiasi messaggio per ricevere il proprio “chat id“.

PROGRAM ST_Telegram
VAR
    MSend : BOOL; (* Message send command *)
    CaseNr : USINT; (* Program case *)
    RxMessage : STRING[ 32 ]; (* Received message buffer *)
    TxMessage : STRING[ 32 ]; (* Transmission message buffer *)
    TCPClient : SysTCPClient; (* TCP client management *)
    TLSClient : SysTLSClient; (* TLS client *)
    HTTPRq : HTTPClient_v5; (* HTTP client *)
    TGClient : Telegram_v1; (* Telegram client *)
END_VAR

// *****************************************************************************
// PROGRAM "ST_Telegram"
// *****************************************************************************
// The program manages the Telegram messenger. On a command it sends a message
// to a user. On a message reception the message is echoed back to the sender.
// -----------------------------------------------------------------------------

    // -------------------------------------------------------------------------
    // INITIALIZATIONS
    // -------------------------------------------------------------------------
    // Program initializations.

    IF (SysFirstLoop) THEN

        // Set TCPClient parameters.

        TCPClient.PeerAdd:=ADR('api.telegram.org'); //Peer address
        TCPClient.PeerPort:=443; //Peer port
        TCPClient.LocalAdd:=ADR('0.0.0.0'); //Local address
        TCPClient.LocalPort:=0; //Local port
        TCPClient.FlushTm:=50; //Flush time (mS)
        TCPClient.LifeTm:=60; //Life time (S)
        TCPClient.RxSize:=512; //Rx buffer size
        TCPClient.TxSize:=512; //Tx buffer size

        // Set TLSClient parameters.

        TLSClient.SpyOn:=FALSE; //Spy active
        TLSClient.Mode:=TLS_MODE_TCP; //TLS mode
        TLSClient.Server:=TCPClient.PeerAdd; //Server name
        TLSClient.CAFile:=eNULL; //CA file
        TLSClient.CAVerify:=TLS_CA_NONE; //Certificate verify type

        // Set HTTPClient parameters.

        HTTPRq.SpyOn:=FALSE; //Activate the spy
        HTTPRq.KeepAlive:=TRUE; //HTTP keep-alive
        HTTPRq.RMethod:=HTTP_REQUEST#HTTP_POST; //Request method
        HTTPRq.HostName:=TCPClient.PeerAdd; // Hostname
        HTTPRq.Page:=eNULL; //Web page
        HTTPRq.Request:=eNULL; //Request string
        HTTPRq.Header:=eNULL; //HTTP header
        HTTPRq.DBSize:=512; //Data buffer size
        HTTPRq.Timeout:=T#10s; //Execution timeout (S)

        // Set Telegram client parameters.

        TGClient.SpyOn:=TRUE; //Spy On
        TGClient.HTTPClient:=ADR(HTTPRq); //HTTP client
        TGClient.Token:=ADR('8*08***27:AA**++++++++++++++3muqw'); //BOT token
        TGClient.TPolling:=T#30s; //Polling time
    END_IF;

    // -------------------------------------------------------------------------
    // FBs MANAGEMENT
    // -------------------------------------------------------------------------
    // All the needed FBs are managed.

    TCPClient(Connect:=HTTPRq.Connect); //TCP client management
    IF (TCPClient.Fault) THEN CaseNr:=0; END_IF;

    TLSClient(IFile:=TCPClient.File); //TLS client management
    IF (TLSClient.Fault) THEN CaseNr:=0; END_IF;

    HTTPRq(File:=TLSClient.OFile); //HTTP client management
    IF (HTTPRq.Fault) THEN CaseNr:=0; END_IF;

    TGClient(Enable:=TRUE); //Telegram client management
    IF (TGClient.Fault) THEN CaseNr:=0; END_IF;
    TGClient.RxAck:=FALSE; //Rx message acknowledge

    // -------------------------------------------------------------------------
    // PROGRAM SEQUENCIES
    // -------------------------------------------------------------------------
    // Program sequencies.

    CASE (CaseNr) OF

        // ---------------------------------------------------------------------
        // Reset any active commands. 
        // Check if a Telegram send message command has been set.
        // Check if a Telegram message has been received.

        0:
        TGClient.Send:=FALSE; //Send message
        IF (MSend) THEN CaseNr:=10; RETURN; END_IF;
        IF (TGClient.RxDone) THEN CaseNr:=20; RETURN; END_IF;

        // ---------------------------------------------------------------------
        // SEND A TELEGRAM MESSAGE
        // ---------------------------------------------------------------------
        // Define the chat ID to send the message. To know the own chat ID send
        // a message to @userinfobot by your phone app.

        10:
        MSend:=FALSE; //Message send command
        eTO_JUNK(SysVsnprintf(ADR(TxMessage), SIZEOF(TxMessage), ADR('Message Nr:%d'), UDINT_TYPE, ADR(TGClient.TxCounter)));

        TGClient.TxChatID:=12345678; //Tx chat id
        TGClient.TxMessage:=ADR(TxMessage); //Tx message
        TGClient.Send:=TRUE; //Send message
        CaseNr:=CaseNr+1; //Program case

        // ---------------------------------------------------------------------
        // Message sending wait.

        11:
        IF NOT(TGClient.TxDone) THEN RETURN; END_IF;
        TGClient.Send:=FALSE; //Send message
        CaseNr:=0; //Program case

        // ---------------------------------------------------------------------
        // RECEIVE A TELEGRAM MESSAGE
        // ---------------------------------------------------------------------
        // The received message is transfert in the received buffer.

        20:
        eTO_JUNK(Sysmemmove(ADR(RxMessage), TGClient.RxMessage, TGClient.RxMLength));
        TGClient.RxAck:=TRUE; //Rx message acknowledge

        // The received message is send back to the sender.

        TGClient.TxChatID:=TGClient.SChatID; //Tx chat id
        TGClient.TxMessage:=ADR(RxMessage); //Tx message
        TGClient.Send:=TRUE; //Send message
        CaseNr:=CaseNr+1; //Program case

        // ---------------------------------------------------------------------
        // Message sending wait.

        21:
        IF NOT(TGClient.TxDone) THEN RETURN; END_IF;
        TGClient.Send:=FALSE; //Send message
        CaseNr:=0; //Program case
    END_CASE;

// [End of file]