EastronSDM120, Eastron SDM120 energy meter

PROGRAM ST_EastronSDM120_v3
VAR
    i : UDINT; (* Auxiliary variable *)
    Sp : SysSerialPort; (* Serial port management *)
    MMdb : ModbusMaster_v1; (* Modbus master *)
    Meter : ARRAY[ 0..2 ] OF EastronSDM120_v3; (* SDM120 meter *)
END_VAR

// ****************************************************************************
// PROGRAM "ST_EastronSDM120_v3"
// ****************************************************************************
// This program manages 3 Eastron SDM120 energy meters.
// -----------------------------------------------------------------------------

    // -------------------------------------------------------------------------
    // INITIALIZATION
    // -------------------------------------------------------------------------
    // Program initializations.

    IF (SysFirstLoop) THEN

        // Serial port settings.

        Sp.COM:=ADR('COM2'); //COM port definition
        Sp.Baudrate:=2400; //Baudrate
        Sp.Parity:='N'; //Parity
        Sp.DataBits:=8; //Data bits
        Sp.StopBits:=1; //Stop bits
        Sp.DTRManagement:=DTR_AUTO_WO_TIMES; //DTR management
        Sp.DTRComplement:=FALSE; //DTR complement
        Sp.EchoFlush:=FALSE; //Received echo flush
        Sp.DTROnTime:=0; //DTR On time delay (mS)
        Sp.DTROffTime:=0; //DTR Off time delay (mS)
        Sp.FlushTm:=0; //Flush time (mS)
        Sp.RxSize:=0; //Rx buffer size
        Sp.TxSize:=0; //Tx buffer size

        // Modbus master settings.

        MMdb.SpyOn:=TRUE; //Spy On    
        MMdb.Type:=0; //Modbus type    
        MMdb.Timeout:=0.2; //Timeout time (S)    
        MMdb.Delay:=0.1; //Delay time (S)    

        // Meter parameters settings.

        Meter[0].Node:=1; //Modbus node
        Meter[0].MMdb:=ADR(MMdb); //ModbusMaster pointer

        Meter[1].Node:=2; //Modbus node
        Meter[1].MMdb:=ADR(MMdb); //ModbusMaster pointer

        Meter[2].Node:=3; //Modbus node
        Meter[2].MMdb:=ADR(MMdb); //ModbusMaster pointer
    END_IF;

    // -------------------------------------------------------------------------
    // ENERGY METERS MANAGEMENT
    // -------------------------------------------------------------------------
    // Manage the Modbus communication.

    Sp(Open:=TRUE); //Serial port management
    MMdb.File:=Sp.File; //File pointer    
    MMdb(); //Modbus master

    // Manage the energy meters.

    Meter[0].Enable:=NOT(Meter[2].Done); //FB enable
    Meter[1].Enable:=Meter[0].Done; //FB enable
    Meter[2].Enable:=Meter[1].Done; //FB enable
    FOR i:=0 TO 2 DO Meter[i](); END_FOR;

// [End of file]

PROGRAM SDM120SetUp
VAR
    Read : BOOL; (* Read command *)
    Write : BOOL; (* Write command *)
    NodeID : USINT; (* Modbus node ID *)
    i : UDINT; (* Aux counter *)
    MeterID : REAL; (* Meter ID *)
    DBuffer : DWORD; (* Data buffer *)
    Sp : SysSerialPort; (* Serial port *)
    Mdb : ModbusMaster_v1; (* Modbus master FB *)
END_VAR

// *****************************************************************************
// PROGRAM "SDM120SetUp"
// *****************************************************************************
// This program allows to read and write a SDM120 meter register. With it you
// can set one by one all the configuration registers. To access to the
// configuration registers you must press the button on the front of the meter
// for about 3 seconds until the "-SEt-" message appears on the display. 
// -----------------------------------------------------------------------------

    // -------------------------------------------------------------------------
    // INITIALIZATION
    // -------------------------------------------------------------------------
    // Program initializations.

    IF (SysFirstLoop) THEN

        // Serial port settings.

        Sp.COM:=ADR('COM2'); //COM port definition
        Sp.Baudrate:=2400; //Baudrate
        Sp.Parity:='N'; //Parity
        Sp.DataBits:=8; //Data bits
        Sp.StopBits:=1; //Stop bits
        Sp.DTRManagement:=DTR_AUTO_WO_TIMES; //DTR management
        Sp.DTRComplement:=FALSE; //DTR complement
        Sp.EchoFlush:=FALSE; //Received echo flush
        Sp.DTROnTime:=0; //DTR On time delay (mS)
        Sp.DTROffTime:=0; //DTR Off time delay (mS)
        Sp.FlushTm:=0; //Flush time (mS)
        Sp.RxSize:=0; //Rx buffer size
        Sp.TxSize:=0; //Tx buffer size

        // Modbus master settings.

        Mdb.SpyOn:=TRUE; //Spy On
        Mdb.Type:=0; //Modbus type (RTU)
        Mdb.Address:=21; //Modbus register address    
        Mdb.Points:=2; //Modbus register points    
        Mdb.Buffer:=ADR(DBuffer); //Memory buffer address    
        Mdb.Timeout:=0.5; //Timeout time (S)
        Mdb.Delay:=0.5; //Delay time (S)
    END_IF;

    // -------------------------------------------------------------------------
    // MODBUS MANAGEMENT
    // -------------------------------------------------------------------------
    // Serial port management.

    Sp(Open:=TRUE); //Serial port management
    Mdb.File:=Sp.File; //File pointer
    IF NOT(SysFIsOpen(Mdb.File)) THEN RETURN; END_IF;

    // Set FB to read the MeterID register.

    IF (Read) THEN
        Mdb.FCode:=16#03; //Modbus function code    
        Mdb.Enable:=TRUE; //Modbus enable
    END_IF;

    // Set FB to write the MeterID register.

    IF (Write) THEN
        Mdb.FCode:=16#10; //Modbus function code    
        Mdb.Enable:=TRUE; //Modbus enable
        i:=VarSwap(REAL_TYPE, ADR(DBuffer), ADR(MeterID));
    END_IF;

    // Manage the modbus master communication.

    Mdb.Node:=NodeID; //Device modbus node
    Mdb(); //Modbus master
    IF NOT(Mdb.Done) THEN RETURN; END_IF;

    // If read executed, store the MeterID value.

    IF (Read) THEN i:=VarSwap(REAL_TYPE, ADR(MeterID), ADR(DBuffer)); END_IF;    

    // Reset the commands.

    Read:=FALSE; //Read command
    Write:=FALSE; //Write command
    Mdb.Enable:=FALSE; //Modbus enable

// [End of file]